libapplayermodes_composite = simd.check('pikaoperationlayermode-composite-simd',
  sse2: 'pikaoperationlayermode-composite-sse2.c',
  compiler: cc,
  include_directories: [ rootInclude, rootAppInclude, ],
  dependencies: [
    cairo,
    gegl,
    gdk_pixbuf,
  ],
)

libapplayermodes_normal = simd.check('pikaoperationnormal-simd',
  sse2: 'pikaoperationnormal-sse2.c',
  sse41: 'pikaoperationnormal-sse4.c',
  compiler: cc,
  include_directories: [ rootInclude, rootAppInclude, ],
  dependencies: [
    cairo,
    gegl,
    gdk_pixbuf,
  ],
)

libapplayermodes_sources = files(
  'pika-layer-modes.c',
  'pikaoperationantierase.c',
  'pikaoperationbehind.c',
  'pikaoperationdissolve.c',
  'pikaoperationerase.c',
  'pikaoperationlayermode-blend.c',
  'pikaoperationlayermode-composite.c',
  'pikaoperationlayermode.c',
  'pikaoperationmerge.c',
  'pikaoperationnormal.c',
  'pikaoperationpassthrough.c',
  'pikaoperationreplace.c',
  'pikaoperationsplit.c',
)

libapplayermodes = static_library('applayermodes',
  libapplayermodes_sources,
  link_with: [
    libapplayermodes_composite[0],
    libapplayermodes_normal[0],
  ],
  include_directories: [ rootInclude, rootAppInclude, ],
  c_args: '-DG_LOG_DOMAIN="Pika-Layer-Modes"',
  dependencies: [
    cairo,
    gegl,
    gdk_pixbuf,
  ],
)