
libpikacolor_sources = files(
  'pikaadaptivesupersample.c',
  'pikabilinear.c',
  'pikacairo.c',
  'pikacmyk.c',
  'pikacolormanaged.c',
  'pikacolorprofile.c',
  'pikacolorspace.c',
  'pikacolortransform.c',
  'pikahsl.c',
  'pikahsv.c',
  'pikapixbuf.c',
  'pikargb-parse.c',
  'pikargb.c',
)

libpikacolor_headers_introspectable = files(
  'pikacolortypes.h',
  'pikaadaptivesupersample.h',
  'pikabilinear.h',
  'pikacairo.h',
  'pikacmyk.h',
  'pikacolormanaged.h',
  'pikacolorprofile.h',
  'pikacolorspace.h',
  'pikacolortransform.h',
  'pikahsl.h',
  'pikahsv.h',
  'pikapixbuf.h',
  'pikargb.h',
)

libpikacolor_headers = [
  libpikacolor_headers_introspectable,
  'pikacolor.h',
]

libpikacolor_introspectable = [
  libpikacolor_sources,
  libpikacolor_headers_introspectable,
]


libpikacolor = library('pikacolor-' + pika_api_version,
  libpikacolor_sources,
  include_directories: rootInclude,
  dependencies: [
    cairo, gdk_pixbuf, gegl, lcms, math,
  ],
  c_args: [ '-DG_LOG_DOMAIN="LibPikaColor"', '-DPIKA_COLOR_COMPILATION', ],
  link_with: [ libpikabase, ],
  vs_module_defs: 'pikacolor.def',
  install: true,
  version: so_version,
)

install_headers(
  libpikacolor_headers,
  subdir: pika_api_name / 'libpikacolor',
)


# Test program, not installed
executable('test-color-parser',
  'test-color-parser.c',
  include_directories: rootInclude,
  dependencies: [
    cairo, gdk_pixbuf, gegl, lcms, math,
    babl,
    # glib,
  ],
  c_args: '-DG_LOG_DOMAIN="LibPikaColor"',
  link_with: [ libpikabase, libpikacolor, ],
  install: false,
)
