
if platform_windows
  pika_debug_resume = executable('pika-debug-resume',
    'pika-debug-resume.c',
  )
endif


pikatool = executable('pikatool' + exec_ver,
  'pikatool.c',
  include_directories: rootInclude,
  dependencies: [
    gtk3,
  ],
  link_with: [
    libpikabase,
  ],
  c_args: [
    '-DDATADIR="@0@"'.format(get_option('datadir')),
  ],
  install: true,
)

pika_test_clipboard = executable('pika-test-clipboard' + exec_ver,
  'pika-test-clipboard.c',
  include_directories: rootInclude,
  dependencies: [
    gtk3,
  ],
  install: true,
)

if enable_default_bin and meson.version().version_compare('>=0.61.0')
  install_symlink(fs.name(pikatool.full_path()).replace(exec_ver, ''),
    pointing_to: fs.name(pikatool.full_path()),
    install_dir: get_option('bindir')
  )
  install_symlink(fs.name(pika_test_clipboard.full_path()).replace(exec_ver, ''),
    pointing_to: fs.name(pika_test_clipboard.full_path()),
    install_dir: get_option('bindir')
  )
endif

executable('kernelgen',
  'kernelgen.c',
  include_directories: rootInclude,
  install: false,
)

colorsvg2png = executable('colorsvg2png',
  'colorsvg2png.c',
  native: true,
  dependencies: [
    native_glib,
    native_rsvg
  ],
  # In case b_sanitize was set, we don't really care if the tool has issues (in
  # particular we experienced some memory leaks with b_sanitize=address, within
  # librsvg and we don't want this to break the build).
  override_options: [ 'b_sanitize=none' ],
  install: false,
)
