subdir('lang')

source_splash=meson.project_source_root() + '/data/images/pika-splash.png'

# make PIKA runnable without being installed.
env=environment()

menu_paths=meson.project_build_root() / 'menus:' + meson.project_source_root() / 'menus'
env.set('PIKA_TESTING_MENUS_PATH', menu_paths)

env.set('PIKA_TESTING_PLUGINDIRS', meson.project_build_root() / 'plug-ins:')
env.append('PIKA_TESTING_PLUGINDIRS', meson.project_build_root() / 'plug-ins/python')
env.append('PIKA_TESTING_PLUGINDIRS', meson.project_build_root() / 'plug-ins/common/test-plug-ins/')

env.prepend('GI_TYPELIB_PATH', meson.project_build_root() / 'libpika')
env.prepend('LD_LIBRARY_PATH', meson.project_build_root() / 'libpika')
env.prepend('LD_LIBRARY_PATH', meson.project_build_root() / 'libpikabase')
env.prepend('LD_LIBRARY_PATH', meson.project_build_root() / 'libpikacolor')
env.prepend('LD_LIBRARY_PATH', meson.project_build_root() / 'libpikaconfig')
env.prepend('LD_LIBRARY_PATH', meson.project_build_root() / 'libpikamath')
env.prepend('LD_LIBRARY_PATH', meson.project_build_root() / 'libpikamodule')
env.prepend('LD_LIBRARY_PATH', meson.project_build_root() / 'libpikathumb')
env.prepend('LD_LIBRARY_PATH', meson.project_build_root() / 'libpikawidgets')

if enable_console_bin
  pika_exe=pikaconsole_exe
else
  pika_exe=pikamain_exe
endif

installsplash = custom_target('installsplash-devel.bmp',
  input : [ 'splash2installer.py' ],
  depend_files: [ source_splash ],
  output: [ 'installsplash-devel.bmp', ],
  command: [ pika_exe, '-nidfs', source_splash,
             '--batch-interpreter', 'python-fu-eval',
             '-b', '-', '--quit'],
  feed: true,
  build_by_default: true,
  env: env
)
